#!/usr/bin/perl

use lib '/home/dailyphoto/htdocs/content';
use lib '/home/lib';
#---------------------------------------------------------------------
#---------------------------------------------------------------------

use CNET::lib;
use strict;
use CGI::Fast;

#---------------------------------------------------------------------
#---------------------------------------------------------------------

use wsys::DPGlobals;
use webshots::WebshotsUser;
use webshots::SuperLogEvent;
use weather::WeatherUtility;

#---------------------------------------------------------------------
#---------------------------------------------------------------------

my $CUSTOMIZE_CITY_TABLE = <<EOM;
<table width=300>
_BODY_
</table>
EOM

my $CUSTOMIZE_CITY_ROW = <<EOM;
<tr>
<td width=200>
	_CITYNAME_
</td>
<td align=left>
	<a href="_UPLINK_"><img src="/img/up_arrow.gif" border=0></a>
	<a href="_DOWNLINK_"><img src="/img/down_arrow.gif" border=0></a>
	<a href="_DELLINK_"><img src="/img/close.gif" border=0></a>
</td>
</tr>
EOM

#---------------------------------------------------------------------
# define main mappings and other worth globals
#---------------------------------------------------------------------

my %CODE_TO_DESCRIPTION;	# maps a city code to a city description
my %REGION_TO_CODEARRAY;	# maps a region code (state or country) to an array of city codes
my %REGION_DESCRIPTION;		# maps a region code to a region description
my %STATE_LIST;				# list of state region codes
my %COUNTRY_LIST;			# list of county region codes
my %SEARCHABLE_CITY_MAP;	# mapping of searchable city entries (DESC|CODE)
my @SEARCHABLE_CITY_LIST;	# array of searchable city codes (DESC|CODE)

ReadCityCodeInfoFile("data/citylist.txt");

my $STATES_OPTION_BLOCK		= GetOptionListForRegion(\%STATE_LIST);
my $COUNTRY_OPTION_BLOCK	= GetOptionListForRegion(\%COUNTRY_LIST);

my $SEARCH_RESULTS_TEMPLATE = DPGlobals::ReadFile("search_results_template.html");

my $CUSTOMIZE_TEMPLATE		= DPGlobals::ReadFile("customize_weather_main_template.html");


my $DISPLAY_TEMPLATE		= DPGlobals::ReadFile("display_weather_main_template.html");
my $DISPLAY_SEARCH_RESULTS_TEMPLATE = DPGlobals::ReadFile("display_search_results_template.html");

my $FORCE_EXIT	= 0;

#---------------------------------------------------------------------
#---------------------------------------------------------------------

CONTINUE:
while (my $cgi = new CGI::Fast)
{
	my $user	= new WebshotsUser;

	my $action			= $cgi->param("action");		# the action to perform
														# (add, showlist, del, up, down, display)
	my $searchcity		= $cgi->param("search");		# search city if applicable
	my $citycode		= $cgi->param("city");			# citycode if applicable
	my $highlightcity	= $cgi->param("highlightcity");	# citycode to highlight if applicable
	my $displaymode		= $cgi->param("displaymode");	# should we show display or add links


#######################################################
#------------------------------------------------------
#
# CGI_STATE: search for a city
#
#------------------------------------------------------
#######################################################

	if ($searchcity)
	{
		if (length($searchcity)<2)
		{
			DPGlobals::DisplayErrorPage("You must enter at least the first TWO letters of the city.");
			$FORCE_EXIT ? exit : next CONTINUE;
		}

		my @list;

		#------------------------------------------------------
		# lookup by zipcode if available, otherwise by cityname
		#------------------------------------------------------

		my $city;
		my $state;
		
		($city,$state) = WebshotsUser::LookupCityStateForZipCode($searchcity);
		if ($city)
		{
			$searchcity="$city, $state";
			lc($searchcity);
			@list = SearchForCity($searchcity);

			# if we found a city, but the search failed, display special msg
			if ($city && @list==0)
			{
				DPGlobals::DisplayErrorPage("We do not have a listing specifically for <b>$searchcity</b>, you might try typing in the name of a larger nearby city.");
				$FORCE_EXIT ? exit : next CONTINUE;
			}

		}
		else
		{
			# no matching zipcode, lookup by city name
			@list = SearchForCity($searchcity);
		}

		
		@list = sort(@list);

		#------------------------------------------------------

		if (@list==0)
		{
			$searchcity = uc($searchcity);
			DPGlobals::DisplayErrorPage("No matching cities were found that begin with the letters <b>$searchcity</b>");
			$FORCE_EXIT ? exit : next CONTINUE;
		}

		#------------------------------------------------------

		if (@list==1)
		{
			# only ONE city, just add it by simulating the 'add' or 'display' command
			# and falling through
			if ($displaymode)
			{
				$action = 'display';
			}
			else
			{
				$action	= 'add';
			}
			$citycode	= $list[0];
		}
		else
		{
			#
			# more than one city,display list
			#
			my $insert = CreateCityListHTML(\@list, $displaymode ? 'display' : 'add');
			my $results_page = ($displaymode==0 ? $SEARCH_RESULTS_TEMPLATE : $DISPLAY_SEARCH_RESULTS_TEMPLATE);
			$results_page =~ s/_RESULTS_/$insert/;
			my $text = DPGlobals::GetMetaPageHTML
						(
						TITLE		=> "Customize Weather",
						R_CORE		=> \$results_page,
						MDOCS_OPTIONAL => { -LOGJAM => 'weather'}
							);

			print $cgi->header();
			print $text;
			$FORCE_EXIT ? exit : next CONTINUE;
		}

	}

#######################################################
#------------------------------------------------------
#
# CGI_STATE: show a city list
#
#------------------------------------------------------
#######################################################

	if ($action eq "showlist")
	{
		my $region = $cgi->param("region");
		my $insert =  CreateCityListHTMLForRegion($region, $displaymode ? 'display' : 'add');

		my $results_page = ($displaymode==0 ? $SEARCH_RESULTS_TEMPLATE : $DISPLAY_SEARCH_RESULTS_TEMPLATE);
		$results_page =~ s/_RESULTS_/$insert/;
		my $text = DPGlobals::GetMetaPageHTML
					(
					TITLE		=> "Customize Weather",
					R_CORE		=> \$results_page,
					MDOCS_OPTIONAL => { -LOGJAM => 'weather'}
						);

		print $cgi->header();
		print $text;

		$FORCE_EXIT ? exit : next CONTINUE;
	}

#######################################################
#------------------------------------------------------
#
# CGI_STATE: view a specific city
#
#------------------------------------------------------
#######################################################

	if ($action eq 'display' && $citycode)
	{
		my $units;
		if (!$user->LoginFromCookieNoFail($cgi))
		{
			$units='e_';
		}
		else
		{
			my %settings;
			my $content = $user->GetContentModuleInfo("WEATHER");		
			WeatherUtility::ParseWeatherContentModuleString($content,\%settings);
			$units = $settings{METRIC} ? 'm_' : 'e_';
		}

		my $file = "/content/weather/html/full/$units$citycode.html";
		print $cgi->redirect($file);
		$FORCE_EXIT ? exit : next CONTINUE;
	}

#######################################################
#------------------------------------------------------
#
# CGI_STATE: pick a city to display from drop boxes
#
#------------------------------------------------------
#######################################################


	if ($action eq '' && $displaymode==1)
	{

		my $maps = DPGlobals::ReadFile("maps_template.html");

		my $text = DPGlobals::GetMetaPageHTML
					(
					TITLE		=> "Lookup Weather",
					R_CORE		=> \$DISPLAY_TEMPLATE,
					MDOCS_OPTIONAL => { -LOGJAM => 'weather'}
						);

		#------------------------------------------------------
		# insert option blocks into combo boxes
		#------------------------------------------------------

		$text =~ s/<option selected value="_STATES_">_<\/option>/$STATES_OPTION_BLOCK/;
		$text =~ s/<option selected value="_COUNTRIES_">_<\/option>/$COUNTRY_OPTION_BLOCK/;
		$text =~ s/_WEATHERMAPS_/$maps/;

		print $cgi->header();
		print $text;
		$FORCE_EXIT ? exit : next CONTINUE;
	}


#######################################################
#
# all the commands below here require a valid user
#
#######################################################

	#------------------------------------------------------
	# get current user
	#------------------------------------------------------
	
	if (!$user->LoginAndReadUser($cgi))
	{
		next CONTINUE;
	}


#######################################################
#------------------------------------------------------
#
# CGI_STATE: updating form
#
#------------------------------------------------------
#######################################################

	if ($action eq 'updating')
	{
		my $content = $user->GetContentModuleInfo("WEATHER");
		my %settings;
		WeatherUtility::ParseWeatherContentModuleString($content,\%settings);
		my $units = $cgi->param("UNITS");
		if ($units eq 'm')
		{
			$settings{METRIC} = 1;
		}
		else
		{
			$settings{METRIC} = 0;
		}
		$settings{MAPS} = $cgi->param("MAPS");
		$content = GenerateWeatherContentModuleString(\%settings);
		$user->SetContentModuleInfo("WEATHER", $content);
		$user->UpdateUserAndRedirect($cgi, "/");
		$FORCE_EXIT ? exit : next CONTINUE;
	}



#######################################################
#------------------------------------------------------
#
# CGI_STATE: process add, move, delete actions
#
#------------------------------------------------------
#######################################################

	if ($action eq 'add' || $action eq 'up' || $action eq 'del' || $action eq 'down')
	{
		if ($citycode)
		{
			ProcessAction($user, $action, $citycode);
			$user->UpdateUserAndRedirect($cgi, "weather.fcgi?highlightcity=$citycode");
		}
		$FORCE_EXIT ? exit : next CONTINUE;
	}

#######################################################
#------------------------------------------------------
#
# CGI_STATE: main customization page
#
#------------------------------------------------------
#######################################################

	my $text = DPGlobals::GetMetaPageHTML
				(
				TITLE		=> "Customize Weather",
				R_CORE		=> \$CUSTOMIZE_TEMPLATE,
				);

	#------------------------------------------------------
	# insert option blocks into combo boxes
	#------------------------------------------------------

	$text =~ s/<option selected value="_STATES_">_<\/option>/$STATES_OPTION_BLOCK/;
	$text =~ s/<option selected value="_COUNTRIES_">_<\/option>/$COUNTRY_OPTION_BLOCK/;

	#------------------------------------------------------
	# parse users current signs into %settings hash
	#------------------------------------------------------

	my %settings;
	my $content = $user->GetContentModuleInfo("WEATHER");
	WeatherUtility::ParseWeatherContentModuleString
		(
			$content, 
			\%settings
		);

	my $r_cities = $settings{CITIES};
	my $metric   = $settings{METRIC} ? 1 : 0;

	#------------------------------------------------------
	# insert units
	#------------------------------------------------------

	if ($metric)
	{
		$text =~ s/_m_SELECTED/checked/;
		$text =~ s/_e_SELECTED//;
	}
	else
	{
		$text =~ s/_m_SELECTED//;
		$text =~ s/_e_SELECTED/checked/;
	}

	#------------------------------------------------------
	# show maps settings
	#------------------------------------------------------

	my $mapson	 = $settings{MAPS};
	if ($mapson)
	{
		$text =~ s/_MAPS_CHECKED_/checked/;
	}
	else
	{
		$text =~ s/_MAPS_CHECKED_//;
	}
	
	#------------------------------------------------------
	# generate city listings for customization mode
	#------------------------------------------------------

	my $body;

	my $citycode;
	foreach $citycode (@$r_cities)
	{
		my $desc = $CODE_TO_DESCRIPTION{$citycode};
		if ($highlightcity eq $citycode)
		{
			$desc = '<b>' . $desc . '</b>';
		}

		my $row = $CUSTOMIZE_CITY_ROW;
		$row =~ s/_CITYNAME_/$desc/;

		my $uplink = GetCallbackLink($citycode,"up");
		my $dnlink = GetCallbackLink($citycode,"down");
		my $dllink = GetCallbackLink($citycode,"del");

		$row =~ s/_UPLINK_/$uplink/;
		$row =~ s/_DOWNLINK_/$dnlink/;
		$row =~ s/_DELLINK_/$dllink/;

		$body.= $row;
	}

	my $body2 = $CUSTOMIZE_CITY_TABLE;
	$body2 =~ s/_BODY_/$body/;
	$text =~ s/_CITYLISTINGS_/$body2/;

	#------------------------------------------------------
	# output!
	#------------------------------------------------------

	print $cgi->header();
	print $text;
	$FORCE_EXIT ? exit : next CONTINUE;
}


#######################################################
#------------------------------------------------------
#
# subroutines
#
#------------------------------------------------------
#######################################################

sub GenerateWeatherContentModuleString
{
	my $r_hash = $_[0];

	my @tags;
		
	#------------------------------------
	# insert units tag
	#------------------------------------

	push @tags, sprintf("u=%s", $r_hash->{METRIC} ? 'm' : 'e');

	#------------------------------------
	# insert maps tag
	#------------------------------------

	push @tags, sprintf("m=%d", $r_hash->{MAPS} ? '1' : '0');


	#------------------------------------
	# insert cities tag
	#------------------------------------

	push @tags, "c=" . join(";", @{$r_hash->{CITIES}});

	return join(" ", @tags);
}

#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub GetCallbackLink
{
	my $citycode = $_[0];
	my $action = $_[1];
	return "weather.fcgi?city=$citycode&action=$action";
}

#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub ProcessAction
{
	my $user		=	$_[0];
	my $action		=	$_[1];
	my $citycode	=	$_[2];

	#------------------------------------------------
	# extract current content string and city list
	#------------------------------------------------

	my $content_string = $user->GetContentModuleInfo("WEATHER");
	my %settings;
	WeatherUtility::ParseWeatherContentModuleString($content_string,\%settings);

	my $r_cities = $settings{CITIES};

	#------------------------------------------------
	# see if city is in list
	#------------------------------------------------

	my $curcitypos=-1;
	CITY: for (my $i=0;$i<@$r_cities;$i++)
	{
		if ($r_cities->[$i] eq $citycode)
		{
			$curcitypos = $i;
			last CITY;
		}
	}
	#------------------------------------------------
	# process city move up
	#------------------------------------------------

	if ($action eq 'up')
	{
		MoveCity($r_cities, $citycode, -1);
	}

	#------------------------------------------------
	# process city move down
	#------------------------------------------------

	if ($action eq 'down')
	{
		MoveCity($r_cities,, $citycode, 1);
	}

	#------------------------------------------------
	# process city add
	#------------------------------------------------

	if ($action eq 'add')
	{
		if ($curcitypos==-1)
		{
			push @$r_cities, $citycode, 
		}
	}

	#------------------------------------------------
	# process city delete
	#------------------------------------------------

	if ($action eq 'del')
	{
		if ($curcitypos>=0)
		{
			splice @$r_cities, $curcitypos, 1;
		}
	}

	#------------------------------------------------
	# set new content string
	#------------------------------------------------

	$content_string = GenerateWeatherContentModuleString(\%settings);
	$user->SetContentModuleInfo("WEATHER", $content_string);
}

#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub MoveCity
{
	my $r_cities = $_[0];
	my $citycode = $_[1];
	my $delta	 = $_[2];

	# find city code

	my $i;
	CITY: for ($i=0;$i<@$r_cities;$i++)
	{
		if ($r_cities->[$i] eq $citycode)
		{
			last CITY;
		}
	}

	# out of range?
	if ($i==@$r_cities)
	{
		return;
	}

	# didn't find city or delta out of range
	my $new = $i+$delta;
	if ($new<0 || $new>=@$r_cities)
	{
		return;
	}

	my $temp = $r_cities->[$new];
	$r_cities->[$new] = $r_cities->[$i];
	$r_cities->[$i]   = $temp;
}

#---------------------------------------------------------------------
#---------------------------------------------------------------------


sub ReadCityCodeInfoFile
{
	my $file = $_[0];

	open(FILE, "<$file");
	while (<FILE>)
	{
		chomp($_);
		my $zone;
		my $region;
		my $region_desc;
		my $city;
		my $code;

		($zone,$region,$region_desc,$city,$code) = split(/\|/, $_);
		
		$zone		 = Trim($zone);
		$region		 = Trim($region);
		$region_desc = Trim($region_desc);
		$city		 = Trim($city);
		$code		 = Trim($code);

		#---------------------------------------------------------
		# add city code to region-2-code mapping
		#---------------------------------------------------------

		if (!defined($REGION_TO_CODEARRAY{$region}))
		{
			$REGION_TO_CODEARRAY{$region} = [];
		}
		push @{$REGION_TO_CODEARRAY{$region}}, $code;
		$REGION_DESCRIPTION{$region} = $region_desc;

		#---------------------------------------------------------
		# add description code to description mapping
		#---------------------------------------------------------

		$CODE_TO_DESCRIPTION{$code} = $city . ", ". $region;

		#---------------------------------------------------------
		# add states to state list
		#---------------------------------------------------------

		if ($zone eq 'U')
		{
			$STATE_LIST{$region} = $code;
		}

		#---------------------------------------------------------
		# add countries to country list
		#---------------------------------------------------------
	
		if ($zone eq 'W')
		{
			$COUNTRY_LIST{$region} = $code;
		}

		#---------------------------------------------------------
		# add to searchable city map
		#---------------------------------------------------------

		$SEARCHABLE_CITY_MAP{$CODE_TO_DESCRIPTION{$code}}  = $code;

	}

	@SEARCHABLE_CITY_LIST = sort(keys %SEARCHABLE_CITY_MAP);

	close(FILE);

};

#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub CreateCityListHTMLForRegion
{
	my $region	= $_[0];
	my $command = $_[1];
	my $r_codelist = $REGION_TO_CODEARRAY{$region};
	return CreateCityListHTML($r_codelist, $command);
}


#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub CreateCityListHTML
{
	my $r_codelist = $_[0];
	my $command	   = $_[1];
	my $code;
	my $body;
	my $display =0;
	if ($command eq 'display')
	{
		$display=1;
	}
	srand(time);
	my $html = <<EOM;
<li><a href="weather.fcgi?action=_COMMAND_&city=_CODE_&rand=_RAND_&displaymode=_DISPLAY_"><small>_DESC_</small></a><br>
EOM
	$body .= '<font size=-1><table align=center><tr><td valign=top><ul>';
	my $count = 0;

	# build a temporary array so we can sort on description
	my @templist;
	foreach $code (@$r_codelist)
	{
		my $desc = lc($CODE_TO_DESCRIPTION{$code});
		push @templist, "$desc|$code";
	}
	@templist = sort(@templist);

	my $half = @templist/2;
	my $colsize = 80;
	if ($half<$colsize)
	{
		$colsize = $half+2;
	}
	foreach (@templist)
	{
		my $junk;
		($junk,$code) = split(/\|/, $_);
		$count++;
		my $work = $html;
		my $rand = rand();
		$work =~ s/_CODE_/$code/;
		$work =~ s/_DESC_/$CODE_TO_DESCRIPTION{$code}/;
		$work =~ s/_RAND_/$rand/;
		$work =~ s/_COMMAND_/$command/;
		$work =~ s/_DISPLAY_/$display/;
		$body .= $work;
		if (($count%$colsize)==0)
		{
			$body .= '</ul></td><td  valign=top><ul>';
		}
	}
	$body .= '</ul><td></tr></table></font>';

	return $body;
}

#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub GetOptionListForRegion
{
	my $r_hash	 = $_[0];
	my $template = <<EOM;
<option _SELECTED_ value="_VALUE_">_DISPLAY_</option>
EOM
	my $body;
	my @regions = sort(keys %$r_hash);
	foreach (@regions)
	{
		if ($_)
		{
			my $block = $template;
			my $desc = $REGION_DESCRIPTION{$_};
			if ($_ && $desc)
			{
				$block =~ s/_SELECTED_//;
				$block =~ s/_VALUE_/$_/;
				$block =~ s/_DISPLAY_/$desc/;
				$body .= $block;
			}
		}
	}

	return $body;
}

#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub SearchForCity
{
	my $search = $_[0];
	$search = Trim($search);
	my @matches = grep /^$search/i, @SEARCHABLE_CITY_LIST;
	my @return;
	foreach (@matches)
	{
		push @return, $SEARCHABLE_CITY_MAP{$_};
	}
	return @return;
}


#---------------------------------------------------------------------
#---------------------------------------------------------------------

sub Trim
{
	my $val = $_[0];
	$val =~ s/^\s+//;
	$val =~ s/\s+$//;
	return $val;
}